code.commongroove.com » T-SQL

T-SQL: Rebuild all user table indexes dynamically

Greg — Wed, 27 Apr 2011 14:17:56 +0000

The more complex the schema, the more indexes you probably have on your tables. Here’s some T-SQL to rebuild all those indexes without having to write out the SQL for each one.

DECLARE @TABLE VARCHAR(255)
DECLARE @cmd NVARCHAR(500)

DECLARE @fillfactor INT
SET @fillfactor = 92

DECLARE table_cursor CURSOR
FOR
SELECT table_catalog + '.' + table_schema + '.' + TABLE_NAME AS full_table_name
FROM MyDatabase.INFORMATION_SCHEMA.TABLES
WHERE table_type = 'BASE TABLE'

OPEN table_cursor

FETCH NEXT FROM table_cursor INTO @TABLE
WHILE @@FETCH_STATUS = 0
BEGIN
SET @cmd = 'ALTER INDEX ALL ON ' + @TABLE + ' ' +
'REBUILD WITH (FILLFACTOR = ' + CONVERT(VARCHAR(3),@fillfactor) + ')'
EXEC (@cmd)

FETCH NEXT FROM table_cursor INTO @TABLE
END
CLOSE table_cursor
DEALLOCATE table_cursor

You will most likely want to adjust the fill factor and/or the actual ALTER INDEX statement to suit the indexes that you have defined on your tables.

Also, I don’t use DBCC DBREINDEX because it has been deprecated by Microsoft.

Hope this helps!

MS SQL Server: Quick T-SQL to Delete All User Table Data

Greg — Tue, 29 Mar 2011 15:28:20 +0000

Here’s a quick (hack) way to delete all user table data from a Microsoft SQL Server database using the undocumented procedure sp_MSforeachtable. As the name hints, this procedure repeats a SQL statement against all user tables within a database.

This example assumes all identity columns are seeded at 1. You may not be able to do that in your environment.

Also note, you could use TRUNCATE TABLE, but only if you no foreign key constraints on your tables.

EXEC sp_MSforeachtable 'ALTER TABLE ? NOCHECK CONSTRAINT ALL'
EXEC sp_MSforeachtable 'DELETE ?'
EXEC sp_MSforeachtable 'ALTER TABLE ? CHECK CONSTRAINT ALL'
EXEC sp_MSforeachtable 'IF (OBJECTPROPERTY(object_id(''?''), ''TableHasIdentity'') = 1) DBCC CHECKIDENT(''?'',RESEED,1)'

Hope this helps!

Creating a SQL CLR User Defined Function

Greg — Mon, 07 Mar 2011 20:28:07 +0000

Starting with SQL Server 2005, Microsoft added the awesome ability to reference .Net assemblies from your T-SQL procedures. Here’s a quick 5 step overview on how to get up and running with your code-based User Defined Function.

1) Create a project from the Visual C# SQL CLR Database Project template (just so you can get the correct references and get a test harness going).

2) Add a class containing your UDFs. This one does a basic Regular Expression comparison:

public class MyUdf
{
[Microsoft.SqlServer.Server.SqlFunction(IsDeterministic = true)]
public static SqlBoolean FnRegExMatch(string source, string pattern)
{
Match m = Regex.Match(source, pattern,
RegexOptions.CultureInvariant |
RegexOptions.IgnoreCase |
RegexOptions.Singleline
);
return m.Success;
}
}

3) Enable the CLR on your SQL Server instance through the configuration options:

EXEC sp_configure 'show advanced options' , '1'
GO
RECONFIGURE
GO
EXEC sp_configure 'clr enabled' , '1'
GO
RECONFIGURE
GO
EXEC sp_configure 'show advanced options' , '0';
GO

4) Add the assembly and then create a reference to your UDF:

CREATE ASSEMBLY [MyUdfs]
AUTHORIZATION [dbo]
FROM 'C:\SqlServerClr\MyUdf.dll'
WITH PERMISSION_SET = SAFE -- we only have "safe" calls in our lib
GO

CREATE FUNCTION [dbo].[FnRegExMatch](
@SOURCE nvarchar(4000),
@pattern nvarchar(4000)
)
RETURNS BIT
WITH EXECUTE AS CALLER
AS
EXTERNAL NAME [MyUdf].[FnRegExMatch]
GO

5) Now you should be able to call your function:

SELECT dbo.FnRegExMatch('my test string', '\btest\b')

Of course this is just the barest of essentials to get you going with SQL CLR UDFs, but I hope it helps!

T-SQL: Backup All User Databases

Greg — Wed, 18 Aug 2010 14:35:07 +0000

Here’s an easy, generic way to back up all user databases on a SQL Server instance:

DECLARE @name VARCHAR(50) -- database name
DECLARE @path VARCHAR(256) -- path for backup files
DECLARE @fileName VARCHAR(256) -- filename for backup
DECLARE @fileDate VARCHAR(20) -- used for file name

SET @path = 'D:\localBackups\' -- has to be a local path

SELECT @fileDate = CONVERT(VARCHAR(20),GETDATE(),112)

DECLARE db_cursor CURSOR FOR
SELECT name
FROM master.dbo.sysdatabases
WHERE name NOT IN ('master','model','msdb','tempdb')

OPEN db_cursor
FETCH NEXT FROM db_cursor INTO @name

WHILE @@FETCH_STATUS = 0
BEGIN
SET @fileName = @path + @name + '_' + @fileDate + '.BAK'
BACKUP DATABASE @name TO DISK = @fileName

FETCH NEXT FROM db_cursor INTO @name
END

CLOSE db_cursor
DEALLOCATE db_cursor

Hope this helps!

Stored Procedure to Export a Table via BCP

Greg — Wed, 04 Aug 2010 19:18:28 +0000

If you are looking for a generic way to export table data via BCP, here’s how:

CREATE PROCEDURE [dbo].[u_ExportDataViaBcp]
(
@name VARCHAR(100), -- this is the table (or table function) name to export
@file VARCHAR(200), -- output file
@fmt_date INT = 121,
@fmt_decimal INT = 128,
@fmt_money INT = 1,
@fmt_float INT = NULL,
@quoted BIT = 1 -- whether or not varchar fields should be quoted on output
)
AS

SET NOCOUNT ON

--- get the current server instance
DECLARE @server NVARCHAR(128)
SET @server = CONVERT(NVARCHAR(128), SERVERPROPERTY('servername'));

-- get the current db
DECLARE @db NVARCHAR(100)
SET @db = DB_NAME()

-- make sure these tmp tables will be unique
DECLARE @tmpUniqueId VARCHAR(50)
SELECT @tmpUniqueId = REPLACE(CONVERT(VARCHAR(50),NEWID()),'-','')

-- sql that gets executed
DECLARE @tmpSql VARCHAR(8000)

-- the temp tables used
DECLARE @export_temp VARCHAR(100)
SELECT @export_temp = '##BcpExportTmp_' + @tmpUniqueId
DECLARE @export_temp2 VARCHAR(100)
SELECT @export_temp2 = '##BcpExportTmp2_' + @tmpUniqueId

-- Make sure the (global) temp tables have been cleaned up
IF OBJECT_ID('tempdb..' + @export_temp) IS NOT NULL
BEGIN
SELECT @tmpSql = 'DROP TABLE ' + @export_temp
EXEC(@tmpSql)
END
IF OBJECT_ID('tempdb..' + @export_temp2) IS NOT NULL
BEGIN
SELECT @tmpSql = 'DROP TABLE ' + @export_temp2
EXEC(@tmpSql)
END

-- in case we have an error
DECLARE @error VARCHAR(200)

-- USE the database
SELECT @tmpSql = 'USE ' + @db + ';'
PRINT @tmpSql
EXEC(@tmpSql)

-- Execute the use and the select
SELECT @tmpSql = 'SELECT * INTO ' + @export_temp + ' FROM ' + @name + ';'
PRINT @tmpSql
EXEC(@tmpSql)

-- Build 2 lists
-- 1. column names
-- 2. columns converted to nvarchar from their original type
DECLARE
@columnNames VARCHAR(MAX),
@columnConversions VARCHAR(MAX)
SELECT
@columnNames =
COALESCE(@columnNames + ',', '') +
'[' + column_name + ']',
@columnConversions =
COALESCE(@columnConversions + ',', '') +
CASE
WHEN data_type IN ('VARCHAR','NVARCHAR') AND @quoted = 1 THEN '''"'' + [' + column_name + '] + ''"''' -- throw some quotes around it
ELSE -- do some conversion
'CONVERT(VARCHAR(255),[' + column_name + ']' +
CASE
WHEN data_type IN ('NUMERIC', 'DECIMAL') THEN CASE WHEN @fmt_decimal IS NOT NULL THEN ',' + CONVERT(VARCHAR, @fmt_decimal) ELSE '' END
WHEN data_type IN ('MONEY', 'SMALLMONEY') THEN CASE WHEN @fmt_money IS NOT NULL THEN ',' + CONVERT(VARCHAR, @fmt_money) ELSE '' END
WHEN data_type IN ('DATETIME', 'SMALLDATETIME') THEN CASE WHEN @fmt_date IS NOT NULL THEN ',' + + CONVERT(VARCHAR, @fmt_date) ELSE '' END
WHEN data_type IN ('FLOAT', 'REAL') THEN CASE WHEN @fmt_float IS NOT NULL THEN ',' + + CONVERT(VARCHAR, @fmt_float) ELSE '' END
ELSE ''
END + ')'
END +
' AS [' + column_name + ']'
FROM tempdb.INFORMATION_SCHEMA.COLUMNS
WHERE TABLE_NAME = @export_temp

-- execute select query to insert data and column names into new temp table
SELECT @tmpSql =
'SELECT ' + @columnNames + ' ' +
'INTO ' + @export_temp2 + ' ' +
'FROM ( ' +
' SELECT ' + @columnConversions + ', 2 AS tmpsort FROM ' + @export_temp + ' ' +
' UNION ALL ' +
' SELECT ''' + REPLACE(REPLACE(REPLACE(@columnNames, ',', ''', '''),'[',''),']','') + ''', 1 AS tmpsort ' +
' ) AS x ' +
' ORDER BY x.tmpsort; ';

PRINT @tmpSql
EXEC(@tmpSql)

-- Execute the BCP to create the file
SELECT @tmpSql = 'bcp "SELECT * FROM ' + @export_temp2 + '" queryout "' + @file + '" -c -C RAW -t, -T -S' + @server
EXEC master.sys.xp_cmdshell @tmpSql
IF @@ERROR > 0
BEGIN
SELECT @error = 'Couldn''t execute the bcp: ''' + @tmpSql;
RAISERROR(@error, 16, 1)
END

-- Make sure the (global) temp tables have been cleaned up
IF OBJECT_ID('tempdb..' + @export_temp) IS NOT NULL
BEGIN
SELECT @tmpSql = 'DROP TABLE ' + @export_temp
EXEC(@tmpSql)
END
IF OBJECT_ID('tempdb..' + @export_temp2) IS NOT NULL
BEGIN
SELECT @tmpSql = 'DROP TABLE ' + @export_temp2
EXEC(@tmpSql)
END

GO

This does use global temp tables as well as xp_cmdshell, but it also gets the job done.

This is a modified version of the suggestion found here:
http://weblogs.sqlteam.com/mladenp/archive/2006/07/25/10771.aspx

Thanks to them for actually doing the hard work! I just cleaned it up and made it support varied column names, quoted varchar/nvarchar output, and use the current server and database instance.

Shrinking your Transaction Log with SQL Server 2008 to Free Disk Space

Greg — Fri, 05 Feb 2010 00:02:53 +0000

If you have been used to clearing up disk space on your development and test SQL server instance file systems with SQL Server 2000 or SQL Server 2005 by using the famous TRUNCATEONLY option on your transaction logs, you might be disheartened that they have removed this option from SQL Server 2008 (with good reason some might say).

If you do try to use it, you will get the infamous:

‘TRUNCATEONLY’ is not a recognized BACKUP option.

To achieve the same effect with SQL Server 2008, you can toggle the recovery mode for the target database and then call your DBCC SHRINKFILE to clear up disk space hogged by your transaction log.

USE MyDatabase
GO
ALTER DATABASE MyDatabase SET RECOVERY SIMPLE
GO
DBCC SHRINKFILE('MyDatabase_log',1)
GO
ALTER DATABASE MyDatabase SET RECOVERY FULL
GO

(Of course if you are already using simple recovery, you wouldn’t need to toggle.)

Hope this helps!

Don’t get caught by ANSI PADDING, VARCHAR, and trailing whitespace!

Greg — Thu, 28 Jan 2010 01:01:12 +0000

One thing to be aware of when you have VARCHAR columns and are using ANSI PADDING: trailing whitespace is trimmed and not counted in your equality ( = / <> / LIKE) statements, so you might not get the results you are looking to be returned from your query.

In the same vein, the len() function will return the same value for two strings if one has trailing whitespace. If you need to compare those two fields including trailing whitespace values, use datalength() instead.

Here’s some example T-SQL:

DECLARE @TABLE TABLE (FIELD VARCHAR(50))

INSERT @TABLE VALUES ('some text')
INSERT @TABLE VALUES ('some text ')
INSERT @TABLE VALUES (' some text')

-- returns 2 :
-- trailing spaces trimmed,
-- leading spaces count
SELECT '"' + FIELD + '"'
FROM @TABLE
WHERE FIELD = 'some text'

-- also returns 2
SELECT '"' + FIELD + '"'
FROM @TABLE
WHERE FIELD LIKE 'some text'

-- shows the difference between len()
-- and datalength()
SELECT FIELD, LEN(FIELD) AS 'Length', DATALENGTH(FIELD) AS 'DataLength'
FROM @TABLE

Hope this helps!

T-SQL: Change Collation on your LIKE Clause Using COLLATE

Greg — Fri, 24 Jul 2009 22:17:25 +0000

Ever have trouble matching unicode letter equivalents in your T-SQL queries? For example, when you want “Québec” and “Quebec” to be equivalent in your text search query?

This is where specifying Accent Insensative Collation (The “AI” in all those collation codes) comes to the rescue. If your database is already set to an AI collation, then you are all set already, but if not, change your LIKE statement to use something like the following:

SELECT *
FROM MyTable (NOLOCK)
WHERE MyColumn COLLATE SQL_Latin1_General_CP1_CI_AI LIKE '%quebec%'

Hope this helps!